Example: A horizontal subfile displayable on two display sizes

The two displays show the subfile defined in this example as it appears on the 24 x 80 and 27 x 132 display sizes.

 
    COLUMN 1                    COLUMN 2
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX

 
    COLUMN 1                    COLUMN 2
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX
_____ XXXXXXXXXXXXXXXX       _____ XXXXXXXXXXXXXXXX

The following keywords are important in the example:

DSPSIZ
SFLLIN

Subfile records appear in two columns (SFLLIN keyword). The subfile can be displayed on two display sizes (DSPSIZ keyword).

Figure 1. Horizontal subfile on two display sizes

|...+....1....+....2....+....3....+....4....+....5....+....6....+....7....+....8
00010A* HORIZONTAL SUBFILE ON TWO DISPLAY SIZES
00020A*
00030A                                 (1)  DSPSIZ(*DS3 *DS4)
00040A          R SFL1                      SFL
00050A            FLDA          10Y 0I  3 11
00060A            FLDB          16   O  3 23
     A
00070A          R SFLCTL1                   SFLCTL(SFL1)
00080A                                      SFLSIZ(50)
00090A                                 (2)  SFLPAG(16)
00100A  *DS4                           (2)  SFLPAG(40)
00110A                                 (3)  SFLLIN(5)
00120A  *DS4                           (3)  SFLLIN(5)
     A
00130A  01                                  SFLEND
00140A  02                                  SFLDSP
00150A  03                                  SFLDSPCTL
00160A  04                                  SFLCLR
     A
00170A                                  1 21'COLUMN 1'
     A
00180A                                  1 55'COLUMN 2'
     A

Legend:

(1): There is one keyword at the file level, the keyword DSPSIZ (optional). This keyword has two values, *DS3 and *DS4, which indicate that the primary display size is 24 x 80, and the secondary display size is 27 x 132.
(2): The SFLPAG keyword (required), is specified once with a value of 16 and again with a value of 40. The first time it applies to a device with the primary display size (default of *DS3, or 24 x 80); the second time, coded with a condition name of *DS4, it applies to a device with the secondary display size (27 x 132).
(3): The SFLLIN keyword causes a subfile to be displayed horizontally. The parameter value specifies the number of spaces between columns of records. In this example, five spaces separate columns of records on both the 24 x 80 display size (*DS3) and the 27 x 132 display size (*DS4). Because *DS3 is the primary display size, it does not need to be specified in positions 9 through 12.